float w2, h2, lineW = 4.0;
float stageSize = 1.5;
float stageRatio = 1.33;
int nDancers = 9;
int nFrames = 9;
float[][] dx, dy, rz;
float dsize = 25;
float stDst = -90.0;  // distance in front of pin to start (negative?)

void setup()
{
  //size(1200, 1000);
  size(1000, 750);
  background(255);
  smooth();

  w2 = width/2;
  h2 = height/2;
  dx = new float[nDancers][nFrames];
  dy = new float[nDancers][nFrames];
  rz = new float[nDancers][nFrames];
  PFont myFont = createFont("HelveticaNeue", dsize*1.75, true); 
  textFont(myFont);   
  textAlign(CENTER);

  initDancerPositions(-1);
}

void draw()
{
  background(255);
  drawScore();
}

void drawScore()
{
  int rows=3, cols=3;
  float h3 = height/3.0, w3 = width/3.0;
  for(int i=0; i<rows; i++) {
    for(int j=0; j<cols; j++) {
      pushMatrix();
      translate(w3 * i, h3 * j);
      scale(0.33);
      int n = i+j*3;
      drawArrows(n);
      drawStage(n);  
      drawDancers(n);
      popMatrix();  
    }
  }
}

void initDancerPositions(int f)
{
  if(f != -1) {
    for(int i=0; i<nDancers; i++) {
      positionDancer(i, f);
    }
  }
  else {
    for(int j=0; j<nFrames; j++) {
      for(int i=0; i<nDancers; i++) {
        positionDancer(i, j);
      }
    }
  }
}

void mousePressed()
{
  int col = round(mouseX / (width/3));
  int row = round(mouseY / (height/3));
  int frame = col + row*3;
  //println(col+", "+row+" = "+frame);
  initDancerPositions(frame);
}

void drawDancers(int frame)
{
  for(int i=0; i<nDancers; i++) {
    drawDancer(i, frame);
  }
}

void drawArrows(int frame)
{
  for(int i=0; i<nDancers; i++) {
    drawArrow(i, frame);
  }
}

void drawDancer(int i, int frame)
{
  pushMatrix();
  stroke(0);
  fill(0);

  translate(dx[i][frame], dy[i][frame]);
  rotate(radians(rz[i][frame]));

  smooth();
  //translate(0, -dsize);
  strokeWeight(lineW);
  text(char(i+65), 0, dsize*2.25);
  // line(-dsize, dsize, dsize, dsize); // X
  line(0, 0, 0, -2.5*dsize);  // Y
  fill(255);
  if(i==0 || i==1) { fill(0); }
  ellipse(0, 0, dsize, dsize);
  popMatrix();
}

void drawArrow(int i, int frame)
{
  int nxtframe = (frame == nFrames-1) ? 0 : frame+1;
  pushMatrix();
  stroke(0);
  fill(0);
  smooth();
  strokeWeight(lineW);

  // find point in front of dancer to start drawing from
  float th = radians(rz[i][frame]);
  float p1x = dx[i][frame] + stDst * -sin(th);
  float p1y = dy[i][frame] + stDst * cos(th);
  float p4x = dx[i][nxtframe];
  float p4y = dy[i][nxtframe];

  // find tangent point further in front of dancer for bezier control
  //float dst = sqrt((p4x-p1x)*(p4x-p1x) + (p4y-p1y)*(p4y-p1y));
  float tite = 3.0;  // at far, we want 5, at near, we want...
  float p2x = dx[i][frame] + tite * stDst * -sin(th);
  float p2y = dy[i][frame] + tite * stDst * cos(th);

  // find tangent point behind oriented dancer next position
  th = radians(rz[i][nxtframe]);
  float p3x =  p4x + tite * -stDst * -sin(th);
  float p3y =  p4y + tite * -stDst * cos(th);

  //  draw bezier curve for path
  noFill();
  stroke(255);
  strokeWeight(lineW*3);
  bezier(p1x, p1y, p2x, p2y, p3x, p3y, p4x, p4y);
  strokeWeight(lineW);
  stroke(0);
  bezier(p1x, p1y, p2x, p2y, p3x, p3y, p4x, p4y);
  //  line(stx, sty, dx[i][nxtframe], dy[i][nxtframe]);

  float arrowL = 20;
  translate(dx[i][nxtframe], dy[i][nxtframe]);
  float a = dy[i][nxtframe] - p3y;
  float b = dx[i][nxtframe] - p3x;
  th = atan(a/b);
  rotate(th+radians(b>0?-90:90));
  line(0, 0, arrowL, -arrowL);
  line(0, 0, -arrowL, -arrowL);

  popMatrix();
}

void positionDancer(int i, int f)
{
  float h2s = h2 * 0.85;
  float w2s = h2s * stageRatio * 1.1;
  float minX = -w2s * stageSize * 0.5 + w2;
  float maxX = w2s * stageSize * 0.5 + w2;
  float minY = -h2s * stageSize * 0.5 + h2;
  float maxY = h2s * stageSize * 0.5 + h2;

  if((i>0) && (random(1)>.3)) {
    float s = 100;
    float choose = random(1);
    float offset = random(s/2,s*1.5) * (random(1)>0.5?-1:1);
    println(offset);
    if(choose<.2) {
      dx[i][f] = constrain(dx[i-1][f] + offset, minX, maxX);
      dy[i][f] = dy[i-1][f];
    }
    else if(choose<0.4) {
      dx[i][f] = dx[i-1][f];
      dy[i][f] = constrain(dy[i-1][f] + offset, minY, maxY);
    }
    else {
      dx[i][f] = constrain(dx[i-1][f] + offset, minX, maxX);
      float offset2 = random(s/2,s*1.5) * (random(1)>0.5?-1:1);
      dy[i][f] = constrain(dy[i-1][f] + offset2, minY, maxY);
    }
    rz[i][f] = rz[i-1][f] + random(-30, 30);
  }
  else {
    dx[i][f] = random(-w2s, w2s) * stageSize * 0.5 + w2;
    dy[i][f] = random(-h2s, h2s) * stageSize * 0.5 + h2;
    rz[i][f] = random(0, 360);
  }
  //println(dx+" "+dy);
}

void drawStage(int frame)
{
  pushMatrix();
  translate(w2, h2);
  scale(stageSize);
  translate(0, -h2/2);
  stroke(0);
  strokeWeight(lineW/2.0);
  float h43 = height/(2.0*stageRatio);
  line(-h43, 0, -h43, h2);
  line(-h43, h2, h43, h2);
  line(h43, h2, h43, 0);
  text(""+(frame+1), -h43+20, 30);
  popMatrix();
}

void keyPressed()
{
  if(key == ' ') {
    initDancerPositions(-1);
  }
}

// switch from random placement to cluster placements (merge and separate
// * position nearby, with chance of jump to far

// behavioral sim to make them stay apart or attract

// print out high rez with postscript?